Mail Merge using MS Word

[djharsha]

Can any one give me some sample code for Mail merge using document template

its really worth if some one have it

 

[AndrewSmith]

Here's a basic outline of a merge automation. You've not given any real idea of the bahviour you're looking for, so this executes a merge of a template doc and a text file data source. The resulting merged doc is made visible, but you could do all sorts of things from there.

DEFINE VARIABLE chWordApp  AS COM-HANDLE     NO-UNDO.
DEFINE VARIABLE chDoc      AS COM-HANDLE     NO-UNDO.
DEFINE VARIABLE chMerge    AS COM-HANDLE     NO-UNDO.
DEFINE VARIABLE chNewDoc   AS COM-HANDLE     NO-UNDO.
 
&GLOBAL-DEFINE wdSendToNewDocument  0
 
    CREATE "Word.Application" chWordApp.
    chWordApp:ScreenUpdating = TRUE.
    chWordApp:visible        = FALSE.
    chWordApp:displayAlerts  = FALSE.
 
    /* open the template document */
    chDoc = chWordApp:documents:OPEN("c:\MergeTemplate.doc",,YES,FALSE).  
 
    /* set Mail Merge object */
    chMerge = chDoc:MailMerge.      
 
    /* open the data source */
    chMerge:OpenDataSource("c:\MergeData.txt").                   
    chMerge:SuppressBlankLines = FALSE.
 
    /* merge target is a NEW word Doc */
    chMerge:Destination = {&wdSendToNewDocument}.  
 
    /* Run merge */
    chMerge:EXECUTE.                      
 
    /* get handle to new document (the merged one) */
    chNewDoc = chWordApp:ActiveDocument.   
    chNewDoc:fields:update.
    chWordApp:visible = TRUE.
 
    RELEASE OBJECT chDoc.
    RELEASE OBJECT chMerge.    
    RELEASE OBJECT chNewDoc.    
    RELEASE OBJECT chWordApp.

 

[djharsha]

thanks Bro . . . .
ur reply enough for my requirement . . . .

thanks . . . .

 

[seductive]

how do u hide the template document???

 

[djharsha]

chDoc:visible = false.

 

[seductive]

thanks for the reply djharsha, i try it but theres an error..
can you give me a suggestion? i try this code, i want to close only the template document...
because when i run this code it pop up the template and the new document...http://www.progresstalk.com/member.php?15492-djharshahttp://www.progresstalk.com/member.php?15492-djharsha

 

[FredJason]

is this running on webspeed??