Using FILE-INFO

[yoachan]

can anyone tells me about FILE-INFO?
How to use it? I need a folder's file list with each file's size to be displayed to my users via webspeed.

Any help apreciated.

Regards

YoChan

 

[sphipp]

In V9, FILE-INFO can do the following:

DEFINE TEMP-TABLE ttfile NO-UNDO
    FIELD shortname  AS CHARACTER FORM "x(20)"
    FIELD longname   AS CHARACTER FORM "x(60)"
    FIELD attributes AS CHARACTER
    FIELD filesize   AS INTEGER FORM ">>>,>>>,>>>,>>9"
    FIELD createdate AS DATE
    FIELD createtime AS CHARACTER
    FIELD moddate    AS DATE
    FIELD modtime    AS CHARACTER
    INDEX idx1 longname.

DEFINE STREAM sIn.
INPUT STREAM sIn FROM OS-DIR ("c:\").
REPEAT:
    CREATE ttfile.
    IMPORT STREAM sIn ttfile.
    ASSIGN FILE-INFO:FILE-NAME = ttfile.longname.
    IF FILE-INFO:FULL-PATHNAME <> ? THEN ASSIGN ttfile.filesiz    = FILE-INFO:FILE-SIZE
                                                ttfile.createdate = FILE-INFO:FILE-CREATE-DATE
                                                ttfile.createtime = STRING (FILE-INFO:FILE-CREATE-TIME,"hh:mm:ss")
                                                ttfile.moddate    = FILE-INFO:FILE-MOD-DATE
                                                ttfile.modtime    = STRING (FILE-INFO:FILE-MOD-TIME,"hh:mm:ss").
END.
INPUT STREAM sIn CLOSE.
FOR EACH ttfile:
    IF ttfile.shortname = "" THEN DO:
        DELETE ttfile.
        NEXT.
    END.
    DISPLAY ttfile.
END.

V8 hasn't as much info, V10 probably has more.

 

[yoachan]

Thanks!